本工具是为了快速切换网关，上下梯子

切换网关.bat

代码如下：

@echo off
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
rem 设置网络连接名称
set "ConnectionName=以太网" 

rem 设置要修改的网络参数
set "IPAddress=192.168.1.11"
set "SubnetMask=255.255.255.0"
set "Gateway=192.168.1.100"
set "PrimaryDNS=8.8.8.8"
set "SecondaryDNS=114.114.114.114"

rem 检查是否以管理员权限运行
>nul 2>&1 net session || (
    echo 需要以管理员权限运行此脚本！
    pause
    exit /b
)

rem 检查DHCP的值
setlocal enabledelayedexpansion

rem 运行 ipconfig /all 命令，并将输出保存到临时文件
ipconfig /all > temp.txt

rem 检查DHCP的值
for /f "delims=" %%a in ('findstr /n "^" temp.txt ^| findstr /c:"DHCP"') do (
    set "line=%%a"
    set "line=!line:*:=!"
    for /f "tokens=2 delims=:" %%b in ("!line!") do (
        set "value=%%b"
        set "value=!value: =!"
        set "value=!value:,=!"
        rem echo !value!
    )
    goto :done
)

:done

if "!value!" equ "否" (
    echo 当前网络为静态IP, 将自动改为DHCP
    rem 将网络更改为 DHCP 自动设置
	netsh interface ip set address name="%ConnectionName%" source=dhcp
    netsh interface ip set dns name="%ConnectionName%" source=dhcp
    echo 网络设置已更改为 DHCP 自动设置。
) else (
    echo 当前网络为DHCP，将自动改为静态IP
    rem 设置静态IP地址
    netsh interface ip set address name="%ConnectionName%" static %IPAddress% %SubnetMask% %Gateway% 1
    rem 设置DNS服务器
    netsh interface ip set dns name="%ConnectionName%" static %PrimaryDNS% > nul 2>&1
    netsh interface ip add dns name="%ConnectionName%" %SecondaryDNS% index=2 > nul 2>&1
    echo 网络已设置完成。
)

del temp.txt

pause